cmake_minimum_required(VERSION 3.18)
project(gjk_epa_module LANGUAGES C CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

# Include GNUInstallDirs to define CMAKE_INSTALL_INCLUDEDIR, CMAKE_INSTALL_LIBDIR, etc.
include(GNUInstallDirs)

find_package(Python COMPONENTS Interpreter Development.Module NumPy REQUIRED)

execute_process(
  COMMAND "${Python_EXECUTABLE}"
          "-c" "from jax.extend import ffi; print(ffi.include_dir())"
  OUTPUT_STRIP_TRAILING_WHITESPACE OUTPUT_VARIABLE XLA_DIR)
message(STATUS "XLA include directory: ${XLA_DIR}")

execute_process(
  COMMAND "${Python_EXECUTABLE}" -m nanobind --cmake_dir
  OUTPUT_STRIP_TRAILING_WHITESPACE OUTPUT_VARIABLE nanobind_ROOT)
message(STATUS "nanobind root directory: ${nanobind_ROOT}")
find_package(nanobind CONFIG REQUIRED)

set(CCD_DOUBLE OFF)
set(CCD_SINGLE ON)

configure_file(ccd/config.h.cmake.in ccd/config.h)

set(CCD_INCLUDES
  ccd/ccd.h
  ccd/compiler.h
  ccd/ccd_export.h
  ccd/quat.h
  ccd/vec3.h
  "${CMAKE_CURRENT_BINARY_DIR}/ccd/config.h")

set(CCD_SOURCES
  alloc.h
  ccd.c
  dbg.h
  list.h
  mpr.c
  polytope.c
  polytope.h
  simplex.h
  support.c
  support.h
  vec3.c)

add_library(ccd ${CCD_INCLUDES} ${CCD_SOURCES})
set_target_properties(ccd PROPERTIES
  PUBLIC_HEADER "${CCD_INCLUDES}"
  SOVERSION ${CCD_SOVERSION}
  VERSION ${CCD_VERSION})
target_include_directories(ccd PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
  $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)

if(NOT WIN32)
  find_library(LIBM_LIBRARY NAMES m)
  if(NOT LIBM_LIBRARY)
    message(FATAL_ERROR "Could NOT find required library LibM")
  endif()
  target_link_libraries(ccd "${LIBM_LIBRARY}")
  if(BUILD_SHARED_LIBS)
    set(CCD_PKGCONFIG_EXTRA_LIBS -lm PARENT_SCOPE)
  endif()
endif()

export(TARGETS ccd FILE "${CMAKE_BINARY_DIR}/ccd-targets.cmake")

install(TARGETS ccd
  EXPORT ccd-targets
  ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
  INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
  LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
  PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/ccd"
  RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
install(EXPORT ccd-targets DESTINATION "${CMAKE_INSTALL_LIBDIR}/ccd")

macro (check_compiler_visibility)
  include (CheckCXXCompilerFlag)
  check_cxx_compiler_flag(-fvisibility=hidden COMPILER_SUPPORTS_VISIBILITY)
endmacro()

if(UNIX)
  check_compiler_visibility()
  if (COMPILER_SUPPORTS_VISIBILITY)
    set_target_properties(ccd
         PROPERTIES COMPILE_FLAGS "-fvisibility=hidden")
  endif()
endif()

if(NOT WIN32 AND BUILD_TESTING AND NOT CCD_HIDE_ALL_SYMBOLS)
  add_subdirectory(testsuites)
endif()

# ---------------------------------------------------------------------------
# Build the Python module using nanobind.
# ---------------------------------------------------------------------------

nanobind_add_module(_gjk_epa_module gjk_epa_module.cpp)
target_link_libraries(_gjk_epa_module PUBLIC ccd)
target_include_directories(_gjk_epa_module PUBLIC ${XLA_DIR})
install(TARGETS _gjk_epa_module LIBRARY DESTINATION ${SKBUILD_PROJECT_NAME})
